# Maintainer: nezu@nezu.cc
pkgname=ida-pro-patched
_pkgname=ida-pro
pkgver=9.0.240925
pkgrel=3
pkgdesc="IDA - The Interactive Disassembler (Patched)"
arch=('x86_64')
url="https://hex-rays.com/ida-pro/"
license=('custom')
makedepends=('fakechroot')
depends=('python>=3' 'python<4')
options=('!strip')
_name="$_pkgname-$pkgver"
_release_url="https://vaclive.party/software/$_pkgname/releases/download/$pkgver"
source=(
    "$_name.run::$_release_url/ida-pro_90_x64linux.run"
    "$_name.run.sig::$_release_url/ida-pro_90_x64linux.run.sig"
    "patch.py::$_release_url/keygen2.py"
    "patch.py.sig::$_release_url/keygen2.py.sig"
    "$_pkgname.desktop"
)
sha256sums=('159cf8983a0e7b199d6efab5af42eca31a288e7ef2ec44eba6336de4acb8107a'
            'SKIP'
            'da41a74453b5e4b6816c5ed1ad66c8c7a19684c48d23e083bda9d5149966616e'
            'SKIP'
            '445e0498d24676cc81c1f9b81a30241eabd480852561f398e520e6e23d4b97bd')
validpgpkeys=('09BE40243217978201A0440E101BA3F4C612AA41') # nezu <nezu@nezu.cc>

prepare() {
    mkdir -p "$_name/tmp"
    cp "$srcdir/$_name.run" "$_name"
    chmod +x "$_name/$_name.run"
    fakechroot chroot "$srcdir/$_name" "/$_name.run" --mode unattended --unattendedmodeui none --prefix /opt/$_name
    cd "$_name/opt/$_name"
    python3 "$srcdir/patch.py"
    mv -v libida32.so.patched libida32.so
    mv -v libida.so.patched libida.so
    rm uninstall* Uninstall*
}

package() {
    install -dm755 "$pkgdir/opt/$_pkgname"
    cp --preserve=mode,timestamps -r "$srcdir/$_name/opt/$_name/"* "$pkgdir/opt/$_pkgname"

    install -dm755 "$pkgdir/usr/bin"
    ln -s "/opt/$_pkgname/ida" "$pkgdir/usr/bin/ida"

    install -Dm644 "$srcdir/$_name/opt/$_name/appico.png" "$pkgdir/usr/share/pixmaps/$_pkgname.png"
    install -Dm644 "$srcdir/$_pkgname.desktop" "$pkgdir/usr/share/applications/$_pkgname.desktop"
}